string $node[] = `sphere -r 2`;
print("shape node name = "+$node[1]+"\n");
float $angle = `getAttr ($node[1]+".esw")`;
print("end sweep angle = "+$angle+"\n");

Create a sphere and capture the names of its nodes. Print the name of the shape node. Get the value of an attribute. Print the value.

string $node[] = `sphere -r 2`;
setAttr ($node[1] + ".radius") 3.5;

Create a sphere and capture the names of its nodes set a radius value of 3.5 units.

string $n[] = `sphere`;
string $sph[] = `listRelatives -s $n`;
  
// Add the parent attribute...
addAttr -ln  MyColor -at double3 
        -k true $sph[0];
        
// Add the "children" attributes...
addAttr -ln  red -at double 
        -defaultValue 0.0
        -min 0.0 -max 1.0 
        -parent MyColor -k true $sph[0];
addAttr -ln  green -at double 
        -defaultValue 0.0
        -min 0.0 -max 1.0 
        -parent MyColor -k true $sph[0];
addAttr -ln  blue -at double 
        -defaultValue 0.0 
        -min 0.0 -max 1.0 
        -parent MyColor -k true $sph[0];

In this example a color attribute is added to the shape node. It could have been added to the transformation node, for example, instead of referencing $shape[0], $n[0] could have been used.

string $name[] = `pSphere1`;
int    $num = `match "[0-9]+" $name[0]`;
 
print("The numeric part of " + 
      $name[0] + " is " + $num + "\n");

Create a sphere and capture the names of its nodes Use the match command to find ALL the numerals. In this example the name of the transform node only has a single digit but if it had more the + symbol tells match to find them all.

sphere   -name sph -r 1;
cylinder -name cyl -r 0.5 -hr 20;
group -name part1 sph cyl;
 
string $s[] = `sphere -r 1`;
string $c[] = `cylinder -r 0.5 -hr 20`;
string $g = `group $s[0] $c[0]`;

create a named sphere create a named cylinder create a named group

Let Maya assign the names most object creation commands return the names of the transform & shape nodes - hence the string array. However, the group command returns a single name.

string $s[] = `sphere -r 1`;
string $c[] = `cylinder -r 0.5 -hr 20`;
string $g1 = `group $s[0] $c[0]`;
  
string $d1[] = `duplicate`;
// or $d[] = `duplicate $g1`;
xform -os -piv 0 0 0 -t 0 1 0 -ro 0 45 0;
string $d2[] = `duplicate -st`;
string $d3[] = `duplicate -st`;
string $all = `group $g1 $d1 $d2 $d3`;

Create a group to be duplicated.

Make a copy of the original object nodes, there are now two sets of objects in the same location. Rotate and translate the first duplicate 45 degrees. Make a second copy with smart transform applied. Make a third copy with smart transform applied. Group them into a single composite object.

The duplicated objects are independent of each other and of the original group from which they were copied. Changing the size of one object will not effect the sizes of the other objects.

string $s[] = `sphere -r 1`;
string $c[] = `cylinder -r 0.5 -hr 20`;
string $g1 = `group $s[0] $c[0]`;
  
string $n1[] = `instance`;
// or $d[] = `instance $g1`;
xform -os -piv 0 0 0 -t 0 1 0 -ro 0 30 0;
string $n2[] = `instance -st`;
string $n3[] = `instance -st`;
string $all = `group $g1 $n1 $n2 $n3`;

Create a group to be instanced.

Make a reference to the original object nodes. The original group is now drawn twice (in the same location). Rotate and translate the first duplicate 30 degrees. Make a second instance with smart transform applied. Make a third instance with smart transform applied. Group them into a single composite object.

The instanced objects reference the objects in the original group. Changing the size of either the original sphere or cylinder will effect the sizes of the instances.

string $path = `curve -degree 3 
                  -p 0 0 0 -p 2 1 0
                  -p -2 2 0 -p 0 3 0`;
string $c[] = `circle -nr 0 1 0 -r 0.25`;
string $ext[] = `extrude -polygon 0 
                  $c[0] $path`;

Create a path for the extrusion.

Create a profile for the extrusion. Extrude the profile along the path.

string $sph[] = `sphere`;
  
currentTime 1;
setKeyframe ($sph[0] + ".translate");
  
currentTime 30;
move -r -moveY 2;
setKeyframe ($sph[0] + ".translate");
  
playbackOptions -min 1 -max 30;
play;

Create the target object.

Go to the first frame. Set the initial value for the translation attribute.
Go to the last frame. Apply a change to the translation. Set the final value for the translation attribute.
Set the duration of the animation. Begin looping.

string $exp = "";
string $obj[];
 
for($i = 0; $i < 3; $i++)
    {
    $obj = `sphere`;
    move (rand(-3,3)) (rand(-3,3)) (rand(-3,3));
    $exp += "select -r " + $obj[0] + ";\n" +
            "move -moveY (rand(0,2));\n";
    }
$exp += "select -clear;\n";
 
expression -s $exp -ae 1;
playbackOptions -min 1 -max 30;
play;

Declare an empty string that will store the entire expression. Declare a string array for the names of a sphere transform and shape nodes. Create three spheres and add the (expression) text that references each sphere. The move statements on this line merely separates each of the spheres. The expression randomly moves each sphere in Y. This line is optional, but its sometimes useful to ensure that no object remains selected after the expression has been run. Add the expression to the scene graph. Setup a short animation. Begin looping the animation.

global proc string getShapeInput(string $node)
{
// get the shape node
string $shp[] = `listRelatives -shapes $node`;
  
// get the connections of the shape node
string $plugs[] = `listConnections $shp[0]`;
  
// plugs[0] is the "initialShadingGroup"
// plugs[1] is "makeNurbSphere_SOME_NUMBER"
return $plugs[1];
}
  
string $s1[] = `sphere -r 1`;
string $s2[] = `sphere -r 1`;
string $s3[] = `sphere -r 1`;
string $group = `group $s1 $s2 $s3`;
  
string $geoNodes[] = `listRelatives 
                      -children
                      -path $group`;
for($n = 0; $n < size($geoNodes); $n++)
    {
    string $input = getShapeInput($geoNodes[$n]);
    // Perhaps assign a value to one of the 
    // attributes, say, the radius - assuming
    // the geometry is a sphere.
    setAttr ($input + ".radius", 2.0);
    }

This proc assumes the node it is given has a single shape node. If you have a group node the following code will enable you to access each item of geometry in the group. For example, suppose we have 3 spheres in a group.