|
# M.Kesson Sept 2011
# 1 Rename the camera shape nodes to "left" and "right".
# 2 Ensure padding in Render Setting is set to 4.
# 3 Use the pwd command to check you are in your Maya project directory.
# 4 If your maya scene is named "test" the proc would be used as follows,
# % mayaStereo test
# or
# % mayaStereo test 2
# or
# % mayaStereo test -1
# If a frame number is not provided the proc will use the image from
# frame 1. A negative frame number will cause the script to read all
# the images from the "left" and "right" folders.
set count 0
proc mayaStereo { sceneName { frameNum 1 } } {
set pwdPath [pwd]
set rendermanDir [file join $pwdPath "renderman"]
set sceneDir [file join $rendermanDir $sceneName]
set imagesDir [file join $sceneDir "images"]
set leftDir [file join $imagesDir "left"]
set rightDir [file join $imagesDir "right"]
if { [file exists $leftDir] == 0 || [file exists $rightDir] == 0 } {
set msg "The stereo camera shape nodes must be named \"left\" and \"right\".\n"
append msg "The error may be caused by the \"present working director\" of the\n"
append msg "console not \"pointing\" to your Maya project directory. Use the\n"
append msg "pwd command in the console to check your directory."
::RMS::LogMsg ERROR $msg
return
}
# We are dealing with one pair of images so the paths to
# the images are constructed "manually" and then converted.
if { $frameNum >= 0 } {
set padding [format "%04d" $frameNum]
set imageName "$sceneName.$padding.tif"
set leftPath [file join $leftDir $imageName]
set rightPath [file join $rightDir $imageName]
# Final checks
if { [checkFilePaths $leftPath $rightPath] == 0 } {
return
}
convertToAnaglyph $leftPath $rightPath
cleanupIt
return
}
# We are dealing with a sequence of images. It is assumed
# the user wants ALL the tiff files in the "left" and "right"
# directories to be processed as anaglyphs.
set leftTiffs [glob -directory $leftDir *.tif]
set rightTiffs [glob -directory $rightDir *.tif]
set numLeftTiffs [llength $leftTiffs]
set numRightTiffs [llength $rightTiffs]
# There might be more tiffs in one of the directories.
set num $numLeftTiffs
if { $numRightTiffs < $num } {
set num $numRightTiffs
}
for {set n 0} {$n < $num} {incr n} {
set leftPath [lindex $leftTiffs $n]
set rightPath [lindex $rightTiffs $n]
convertToAnaglyph $leftPath $rightPath
}
cleanupIt
}
#=====================================
# Local utility procs
#=====================================
proc checkFilePaths { left right } {
if { [file exists $left] == 0 } {
::RMS::LogMsg ERROR "Cannot find the left image:\n\"$left\"."
return 0
}
if { [file exists $right] == 0 } {
::RMS::LogMsg ERROR "Cannot find the right image:\n\"$right\"."
return 0
}
return 1
}
proc convertToAnaglyph { leftPath rightPath } {
global count
[ice::load $leftPath -h left_raw]
[ice::load $rightPath -h right_raw]
# Grab the rgb channels
it IceExpr "left_rgb := left_raw Shuffle(list(0,1,2))"
it IceExpr "right_rgb := right_raw Shuffle(list(0,1,2))"
it IceExpr "m := list(1,0,0,0, 0,0,0,0, 0,0,0,0) ; right_tinted := right_rgb Cha(m, 3, 4)"
it IceExpr "m := list(0,0,0,0, 0,1,0,0, 0,0,1,0) ; left_tinted := left_rgb Cha(m, 3, 4)"
# Ensure the final output image has a unique (handle) name
# then combine the two images.
set imgname "stereo_$count"
it IceExpr "$imgname := left_tinted Add(right_tinted)"
incr count
}
proc cleanupIt { } {
set cat [it GetCurrentCatalog]
set imgs [$cat GetImageList]
foreach item $imgs {
set h [$item GetHandle]
if { [string equal $h "left_rgb"] } {
$cat DeleteImage $item
} elseif { [string equal $h "right_rgb"] } {
$cat DeleteImage $item
} elseif { [string equal $h "left_tinted"] } {
$cat DeleteImage $item
} elseif { [string equal $h "right_tinted"] } {
$cat DeleteImage $item
}
}
}
|
